Napotki za iskanje po Wikipodatkih

Iz Wikiverza

Graf rojstnih krajev pomembnih Slovencev[uredi]


# Places in Slovenia by number of notable people born there.
# defaultView:BubbleChart
SELECT ?place ?placeLabel ?count
WHERE
{
    {
        SELECT ?place (count(?item) as ?count)
        WHERE
        {
            ?item wdt:P19 ?place .
            ?place wdt:P17 wd:Q215 .
        }
        GROUP BY ?place
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY DESC(?count)

Slovenski literati, umrli med 1941 in 1945[uredi]


# seznam slovenskih literatov, ki so umrli med 1941 in 1945
SELECT DISTINCT ?oseba ?osebaLabel ?kraj_rojstva ?kraj_rojstvaLabel ?datum_rojstva ?datum_smrti ?poklic ?poklicLabel ?kraj_smrti ?kraj_smrtiLabel WHERE
{
  ?oseba wdt:P31 wd:Q5;
    wdt:P19 ?kraj_rojstva.
  ?kraj_rojstva wdt:P17 wd:Q215.
  ?oseba wdt:P569 ?datum_rojstva.
  ?oseba wdt:P570 ?datum_smrti.
  ?oseba wdt:P20 ?kraj_smrti.
  ?oseba wdt:P106 ?poklic.
  FILTER (?poklic in ( wd:Q36180, wd:Q214917, wd:Q11774202, wd:Q49757, wd:Q333634, wd:Q4263842, wd:Q13570226, wd:Q6673651, wd:Q12144794) ) #pisatelj,dramatik, esejist, pesnik, prevajalec, literarni kritik, literarni zgodovinar, literat, pisatelj proze
  FILTER((?datum_smrti >= "1941-01-01T00:00:00Z"^^xsd:dateTime) && (?datum_smrti <= "1945-12-31T00:00:00Z"^^xsd:dateTime)) # rojeni na določen datum
#  FILTER((?datum_rojstva = "1945-01-01T00:00:00Z"^^xsd:dateTime)) # rojeni na določen datum
  SERVICE wikibase:label { bd:serviceParam wikibase:language "sl". }
}

Literati, rojeni v Kranju[uredi]


#Ljudje rojeni v Občini Kranj (Q3441893)
# PAZI: Rezultati so za tiste osebe, ki imajo vpisan kraj rojstva v WD; vsi Slovenci ga namreč nimajo
SELECT ?somebody ?somebodyLabel ?kraj_rojstva ?kraj_rojstvaLabel ?poklic ?poklicLabel WHERE {
  ?somebody wdt:P31 wd:Q5.
  ?somebody wdt:P19 ?kraj_rojstva.
  ?somebody wdt:P106 ?poklic.
  ?kraj_rojstva wdt:P131 wd:Q3441893.
   FILTER ( ?poklic in ( wd:Q36180, wd:Q214917, wd:Q11774202, wd:Q49757, wd:Q333634, wd:Q4263842, wd:Q13570226 ) ) #pisatelj, dramatik, esejist, pesnik, prevajalec, literarni kritik, literarni zgodovinar
 SERVICE wikibase:label { bd:serviceParam wikibase:language "sl,en". }
}

Literati, umrli v Kranju[uredi]


#Ljudje umrli v Občini Kranj (Q3441893)
# PAZI: Rezultati so za tiste osebe, ki imajo vpisan kraj smrti v WD; vsi Slovenci ga namreč nimajo
SELECT ?somebody ?somebodyLabel ?kraj_smrti ?kraj_smrtiLabel ?poklic ?poklicLabel WHERE {
  ?somebody wdt:P31 wd:Q5.
  ?somebody wdt:P20 ?kraj_smrti.
  ?somebody wdt:P106 ?poklic.
  ?kraj_smrti wdt:P131 wd:Q3441893.
   FILTER ( ?poklic in ( wd:Q36180, wd:Q214917, wd:Q11774202, wd:Q49757, wd:Q333634, wd:Q4263842, wd:Q13570226 ) ) #pisatelj, dramatik, esejist, pesnik, prevajalec, literarni kritik, literarni zgodovinar
 SERVICE wikibase:label { bd:serviceParam wikibase:language "sl,en". }
}

Filmske igralke, rojene na območju Slovenije[uredi]


# seznam filmskih igralk rojenih na območju Slovenije
# OPOMBA: na Wikipediji obstaja tudi kategorija Kategorija:Slovenski filmski igralci
# in se lahko še tam preveri, če je še kakšna, ki jo spodnja skripta ne zajame
SELECT DISTINCT ?oseba ?osebaLabel ?flabelLabel ?poklicLabel ?datumRojstva ?krajRojstvaLabel ?datumSmrti ?krajSmrtiLabel WHERE {
  ?oseba wdt:P31 wd:Q5;
    wdt:P21 wd:Q6581072;
    wdt:P106 wd:Q10800557;
    wdt:P19 ?kraj_rojstva.
  ?kraj_rojstva wdt:P17 wd:Q215.
  OPTIONAL { ?oseba wdt:P569 ?datumRojstva. }
  OPTIONAL { ?oseba wdt:P19 ?krajRojstva. }
  OPTIONAL { ?oseba wdt:P570 ?datumSmrti. }
  OPTIONAL { ?oseba wdt:P20 ?krajSmrti. }
  OPTIONAL { ?oseba wdt:P106 ?poklic. }
  OPTIONAL {
    ?poklic wdt:P2521 ?flabel.
    BIND(LANG(?flabel) AS ?lang)
    FILTER(?lang = "sl")
  }
  FILTER(?poklic = wd:Q10800557)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "sl". }
}
ORDER BY (?osebaLabel)

Rojeni in umrli v kaki slovenski občini[uredi]


#Ljudje rojeni v Občini Maribor (Q3435104) ....
# PAZI: Rezultati so za tiste osebe, ki imajo vpisan kraj rojstva v WD, ker ga vsi naši ljubi Slovenci nimajo

SELECT ?somebody ?somebodyLabel ?kraj_rojstva ?kraj_rojstvaLabel WHERE {
  ?somebody wdt:P31 wd:Q5.
  ?somebody wdt:P19 ?kraj_rojstva.
  ?kraj_rojstva wdt:P131 wd:Q3435104.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "sl,en". }
}

#Ljudje umrli v Občini Maribor (Q3435104) ....
# PAZI: Rezultati so za tiste osebe, ki imajo vpisan kraj smrti v WD, ker ga vsi naši ljubi Slovenci nimajo
SELECT ?somebody ?somebodyLabel ?kraj_smrti ?kraj_smrtiLabel WHERE {
  ?somebody wdt:P31 wd:Q5.
  ?somebody wdt:P20 ?kraj_smrti.
  ?kraj_smrti wdt:P131 wd:Q3435104.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "sl,en". }
}

Vsi skripti so delo uporabnice Pinky sl.

Literatura[uredi]